home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FM Towns: Free Software Collection 7
/
FM Towns Free Software Collection 7.iso
/
data
/
pvap322a
/
pvapset.plp
< prev
next >
Wrap
Text File
|
1993-11-30
|
23KB
|
694 lines
/************************************************************************
* ユーザー設定 *
************************************************************************/
/* ユーザー設定メニュー */
%USERSET{
loop({
SNDMSG({erande_f.snd});
footnote({処理を選択して下さい});
select({処理を選択して下さい},
99999,{SETFILE1:={一時設定};im({No})},
{ 通信に必要な項目の設定 },{SETNET;im({Yes})},
{ 各種ディレクトリの設定 },{SETDIR;im({Yes})},
{ 通信メニュー初期値の設定 },{SETMENU;im({Yes})},
{ その他の設定 },{SETHOKA;im({Yes})},
{ 元の設定に戻す },{CANCEL;im({Yes})},
{ 設定をファイルに保存 },{FSAVE;im({Yes})},
{ ファイルから設定を読込 },{FLOAD;im({Yes})},
{ 設定を保存して終了 },{writeSET;im({No})},
{ 保存しない(一時的な変更) },{SETFILE1:={一時設定};im({No})});
});
};
/* 通信に必要な項目の設定 */
%SETNET{
var id[8]; id:= ID;
var pass[8]; pass:= PASS;
var ap[20]; ap:= AP;
var ap2[20]; ap2:= AP2;
var ap3[20]; ap3:= AP3;
var tel[1]; tel:= TEL;
var modem[40]; modem:= MODEM;
var save[12]; save:= SAVE;
var save2[5]; save2:= SAVE2;
var list[2]; list:= LIST;
loop({
%Tel @case(tel={T}, {Yes},{im({2})},,{im({1})});
%Modem {case(modem,{},{im({未設定})},,{head(@tail(modem,{/}),{_})})};
%Save {case (save,
{WHOLE}, {im({全体で一つ})},
{BOARD}, {im({ボード別})},
{JUMPCODE}, {im({ジャンプコード別})},,
{im({未設定})})};
%Save2 {case (save2,
{MONTH}, {im({月に1ファイル})},
{EVERY}, {im({アクセスごと})},
{DAY}, {im({日に1ファイル})},,
{im({未設定})})};
SNDMSG({nyuryo_f.snd});
footnote({通信に必要な項目を設定して下さい});
%set @plane( {c通信に必要な項目を設定して下さい\n}|
{tID /12345678\n}|
{tパスワード /12345678\n}|
{c 何も入力しないとログイン時に入力することが}|
{出来ます\n}|
{t1200bpsのAPの電話番号 /12345678901234567890\n}|
{t2400bpsのAPの電話番号 /12345678901234567890\n}|
{tPC-VAN+のAPの電話番号 /12345678901234567890\n}|
{s 電話番号一覧 / 1200bps / 2400bps }|
{/ PC-VAN+ \n}|
{r電話回線の種類 /ダイアル /プッシュホン \n}|
{cモデムの機種 }|@Modem|{\n}|
{s / モデム一覧 \n}|
{cログの保存の仕方 }|@Save|{ で }|
@Save2|{\n}|
{s / 設定変更 \n}|
{t各種リスト取得時の画面数 /12\n}|
{s/ 設定 / 取消 \n},
id,pass,ap2,ap,ap3,Tel,list);
id:= @head(@getline(set,1,1),{\n});
pass:= @head(@getline(set,2,1),{\n});
ap:= @head(@getline(set,4,1),{\n});
ap2:= @head(@getline(set,3,1),{\n});
ap3:= @head(@getline(set,5,1),{\n});
%sel3 @head(@getline(set,6,1),{\n});
case (@head(@getline(set,7,1),{\n})==1,
{Yes}, {tel:={P}},,
{tel:={T}});
list:= @head(@getline(set,10,1),{\n});
%sel @head(@getline(set,8,1),{\n});
%sel2 @head(@getline(set,9,1),{\n});
%ok @head(@getline(set,11,1),{\n});
case (sel==1,{Yes}, {SETMODEM});
case (sel2==1,{Yes}, {SETLOG});
case (sel3<>{ 0},{Yes},{#PVAPAP.PLP});
case (ok,
{ 1}, {ID:= @head(@getline(set,1,1),{\n});
PASS:= @head(@getline(set,2,1),{\n});
AP:= @head(@getline(set,4,1),{\n});
AP2:= @head(@getline(set,3,1),{\n});
AP3:= @head(@getline(set,5,1),{\n});
MODEM:= modem;
SAVE:= save;
SAVE2:= save2;
case (@head(@getline(set,7,1),{\n})==1,
{Yes}, {TEL:={P}},,
{TEL:={T}});
LIST:= @head(@getline(set,10,1),{\n})},
{ 2}, {im({No})},,
{case (ok={ 0}&&sel={ 0}&&sel2={ 0}&&sel3={ 0},
{Yes}, {im({No})}, /* 右クリックで終了 */
{No}, {im({Yes})})});
});
};
/* ログの保存の仕方の設定 */
%SETLOG{
%Save {case (save,
{WHOLE}, {im({全体で一つ})},
{BOARD}, {im({ボード別})},
{JUMPCODE}, {im({ジャンプコード別})},,
{im({未設定})})};
%Save2 {case (save2,
{MONTH}, {im({月に1ファイル})},
{EVERY}, {im({アクセスごと})},
{DAY}, {im({日に1ファイル})},,
{im({未設定})})};
SNDMSG({erande_f.snd});
footnote({ログの保存の仕方を選択して下さい});
select( {ログの保存の仕方を選択して下さい 現在は }|@Save|{ です},
99999,,
{ 全体で一つ },{save:={WHOLE}},
{ ジャンプコード別 },{save:={JUMPCODE}},
{ ボード別 },{save:={BOARD}},
{ 変更しない },);
SNDMSG({erande_f.snd});
footnote({ログの保存の仕方を選択して下さい});
select( {ログの保存の仕方を選択して下さい 現在は }|@Save2|{ です},
99999,,
{ アクセスごと },{save2:={EVERY}},
{ 日に1ファイル },{save2:={DAY}},
{ 月に1ファイル },{save2:={MONTH}},
{ 変更しない },);
};
/* 通信メニュー初期値の設定 */
%SETMENU{
%Updown @case(UPDOWN={No},{Yes},{im({2})},,{im({1})});
%Billchk@case(BILLCHK={No},{Yes},{im({2})},,{im({1})});
%Preser @case(PRESER={No},{Yes},{im({2})},,{im({1})});
%Acceap @case(ACCEAP, {1200}, {im({1})},
{2400}, {im({2})},
{PC-VAN+},{im({3})},,{im({2})});
%Redial @case (REDIAL,
{5}, {im({1})},
{10}, {im({2})},
{30}, {im({3})},
{9999}, {im({4})},,{im({4})});
%Calami @case(CALAMI, {PVAP},{im({2})},
{MOPT},{im({3})},
{POFF},{im({4})},,{im({1})});
SNDMSG({erande_f.snd});
footnote({通信メニューの初期値を設定して下さい});
%set @plane(
{c通信メニューの初期値を設定して下さい\n}|
{rアップ・ダウンロード処理 /する /しない \n}|
{r課金情報の確認 /する /しない \n}|
{rログの保存 /する /しない \n}|
{rアクセスするAP /1200bps /2400bps /PC-VAN+\n}|
{rリダイアル回数 /5 /10 /30 /無限\n}|
{r通信終了時 /PVAP継続 /PVAP終了 /MOPT終了 /電源切断\n}|
{s/ 設定 / 取消 \n},
Updown,Billchk,Preser,Acceap,Redial,Calami);
%ok @head(@getline(set,7,1),{\n});
case (ok==1,
{Yes}, {case (@head(@getline(set,1,1),{\n})==1,
{Yes}, {UPDOWN:={Yes}},,
{UPDOWN:={No}});
case (@head(@getline(set,2,1),{\n})==1,
{Yes}, {BILLCHK:={Yes}},,
{BILLCHK:={No}});
case (@head(@getline(set,3,1),{\n})==1,
{Yes}, {PRESER:={Yes}},,
{PRESER:={No}});
ACCEAP:=@case (@head(@getline(set,4,1),{\n}),
{ 1},{im({1200})},
{ 2},{im({2400})},
{ 3},{im({PC-VAN+})});
REDIAL:=@case (@head(@getline(set,5,1),{\n}),
{ 1},{im({5})},
{ 2},{im({10})},
{ 3},{im({30})},
{ 4},{im({9999})});
CALAMI:=@case (@head(@getline(set,6,1),{\n}),
{ 1},{im({CONT})},
{ 2},{im({PVAP})},
{ 3},{im({MOPT})},
{ 4},{im({POFF})})},
{No}, {im({No})});
};
/* ディレクトリの設定 */
%selDIR {
[MSG]
footnote(MSG|{まで移動して右クリックして下さい});
SNDMSG({erande_f.snd});
filesel;
im(@getcdir);
};
/* 各種ディレクトリの設定 */
%SETDIR{
var logpath[64]; logpath:=LOGPATH;
var temppath[64]; temppath:=TEMPPATH;
var dir2[64]; dir2:=DIR2;
var titlepath[64]; titlepath:=TITLEPATH;
loop({
SNDMSG({nyuryo_f.snd});
footnote({ディレクトリの設定をして下さい});
%set @plane( {cディレクトリの設定をして下さい\n}|
{cログを保存するディレクトリ\n}|
{s 絶対に設定して下さい! }|
{/ 検索 \n}|
{t/\n}|
{cテンポラリファイルを置くディレクトリ\n}|
{s 絶対に設定して下さい! }|
{/ 検索 \n}|
{t/\n}|
{cTXF・QV・LHA・ISH・DIETを置いているディレクトリ\n}|
{s 設定しないとパスの通ったディレクトリになります}|
{/ 検索 \n}|
{t/\n}|
{c未読タイトルのリストを置くディレクトリ\n}|
{s 他のディレクトリと同じ場所にはしないで下さい }|
{/ 検索 \n}|
{t/\n}|
{c ルートディレクトリ以外は最後の「\」は不要です\n}|
{s/ 設定 / 取消 \n},
logpath,temppath,dir2,titlepath);
%sel @head(@getline(set,1,1),{\n});
logpath:=@head(@getline(set,2,1),{\n});
%sel2 @head(@getline(set,3,1),{\n});
temppath:=@head(@getline(set,4,1),{\n});
%sel3 @head(@getline(set,5,1),{\n});
dir2:= @head(@getline(set,6,1),{\n});
%sel4 @head(@getline(set,7,1),{\n});
titlepath:=@head(@getline(set,8,1),{\n});
%ok @head(@getline(set,9,1),{\n});
case (sel==1,{Yes},
{logpath:=@selDIR({ログを保存するディレクトリ})});
case (sel2==1,{Yes},
{temppath:=@selDIR({テンポラリファイルを}|
{置くディレクトリ})});
case (sel3==1,{Yes},
{dir2:=@selDIR({フリーウェアを置くディレクトリ})});
case (sel4==1,{Yes},
{titlepath:=@selDIR({未読タイトルを置くディレクトリ})});
case (ok,
{ 1}, {LOGPATH:= @head(@getline(set,2,1),{\n});
case (@nochar(LOGPATH),
{3},{LOGPATH:=@getchar(LOGPATH,{1},{2})});
mkdir2(LOGPATH);
TEMPPATH:= @head(@getline(set,4,1),{\n});
case (@nochar(TEMPPATH),
{3},{TEMPPATH:=@getchar(TEMPPATH,{1},{2})});
mkdir2(TEMPPATH);
DIR2:= @head(@getline(set,6,1),{\n});
case (@nochar(DIR2),
{3},{DIR2:=@getchar(DIR2,{1},{2})});
TITLEPATH:= @head(@getline(set,8,1),{\n});
case (@nochar(TITLEPATH),
{3},{TITLEPATH:=@getchar(TITLEPATH,{1},{2})});
mkdir2(TITLEPATH)},
{ 2}, {im({No})},,
{case (ok={ 0}&&sel={ 0}&&sel2={ 0}
&&sel3={ 0}&&sel4={ 0},
{Yes}, {im({No})},
{No}, {im({Yes})})});
});
};
/* その他の設定 */
%SETHOKA{
loop({
SNDMSG({erande_f.snd});
footnote({処理を選択して下さい});
select( {処理を選択して下さい},99999,{im({No})},
{ 背景色設定 },{setCOLOR;im({Yes})},
{ 入力時のプロンプト方法設定 },{setPRMPT;im({Yes})},
{ 使用ファイルマネージャ設定 },{setFMGR;im({Yes})},
{ 終 了 },{im({No})});
});
};
/* ファイルマネージャの選択 */
%setFMGR{
%mgr @case(FMGR,{},{im({標準ファイルマネージャ})},,{im(FMGR)});
SNDMSG({erande_f.snd});
footnote({ファイルマネージャを選択して下さい 現在は }|mgr|{ です});
FMGR:=
@loop ({select({ファイルマネージャを選択して下さい},
99999,{im(FMGR)},
{ 標準ファイルマネージャ },{im({})},
{ 任意のファイルマネージャ },
{
footnote({ファイルマネージャ用のオート}|
{パイロットを指定して下さい});
%fmgr @filesel();
case(fmgr,{},{im({})},
,{case(@nochar(@getcdir),
{3},{im(@getcdir|fmgr)},
,{im(@getcdir|{\}|fmgr)})});
});
});
};
/* 入力プロンプトの設定 */
%setPRMPT{
SNDMSG({erande_f.snd});
footnote({入力時のプロンプト方法を指定して下さい});
select ({入力時のプロンプト方法を指定して下さい},
99999,,
{ 音声メッセージ },
{VBELL:={No};setSNDDIR;visibell(VBELL)},
{ ブザー音 },
{SOUND:={};VBELL:={No};visibell(VBELL)},
{ 画面フラッシュ },
{SOUND:={};VBELL:={Yes};visibell(VBELL)},
{ 指定のsndファイル },
{SOUND:={};VBELL:={No};setBELFIL;visibell(VBELL)});
};
/* bellfileの設定 */
%setBELFIL{
SNDMSG({erande_f.snd});
footnote({ベルの代わりに鳴らす音声ファイルを指定して下さい});
%bell @filesel({SND});
%bell2 {case (@nochar(@getcdir),{3},{im(@getcdir|bell)},
,{im(@getcdir|{\}|bell)})};
case (bell,{},{BELFIL:={}},,{BELFIL:=@bell2});
case (@tail(BELFIL,{.})={snd}||@tail(BELFIL,{.})={SND},
{Yes},{bellfile(BELFIL)});
};
/* 音声メッセージファイルの設定 */
%setSNDDIR{
SNDMSG({nyuryo_f.snd});
footnote({音声メッセージファイルを格納するディレクトリを}|
{指定して下さい});
SOUND:= @input( {音声メッセージファイルを置く}|
{ディレクトリを指定して下さい\n}|
{ ルートディレクトリ以外は最後の「\」は不要です\n}|
{ (例)A:\MOPTERM\SOUND},,SOUND);
case (@nochar(SOUND),
{3},{SOUND:=@getchar(SOUND,{1},{2})});
mkdir2 (SOUND);
case (@filechk(SOUND|{erande_f.snd})&&
@filechk(SOUND|{nyuryo_f.snd})&&
@filechk(SOUND|{kaknin_f.snd})&&
@filechk(SOUND|{okasi_f.snd})&&
@filechk(SOUND|{owata_f.snd})&&
@filechk(SOUND|{jikan_f.snd}),
{No},{copySND(SOUND|{\})});
};
/* 音声メッセージファイルのコピー */
%copySND{
[snddir] /* 最後は「\」であること */
display (BELL);
footnote({システムCDをセットして下さい});
select ({システムCDをセットして下さい},
99999,,
{ OK },
{case (@setcdir({q:\fj\msg}), /* v1.1 */
{Yes},
{footnote({erande_f.sndをコピーします});
command({copy order\erande_f.snd }|snddir|{*.*});
footnote({nyuryo_f.sndをコピーします});
command({copy order\nyuryo_f.snd }|snddir|{*.*});
footnote({kaknin_f.sndをコピーします});
command({copy order\kaknin_f.snd }|snddir|{*.*});
footnote({owata_f.sndをコピーします});
command({copy info\owata_f.snd }|snddir|{*.*});
footnote({okasi_f.sndをコピーします});
command({copy alarm\okasi_f.snd }|snddir|{*.*})},
{No},
{case (@setcdir({q:\fj2\msg}), /* v2.1 */
{Yes},
{footnote({erande_f.sndをコピーします});
command({copy order\erande_f.snd }|
snddir|{*.*});
footnote({nyuryo_f.sndをコピーします});
command({copy order\nyuryo_f.snd }|
snddir|{*.*});
footnote({kaknin_f.sndをコピーします});
command({copy order\kaknin_f.snd }|
snddir|{*.*});
footnote({owata_f.sndをコピーします});
command({copy info\owata_f.snd }|snddir|{*.*});
footnote({okasi_f.sndをコピーします});
command({copy warning\okasi_f.snd }|
snddir|{*.*})})});
footnote({});setcdir(DIR1);},
{ NO },);
};
/* 背景色の設定をする */
%setCOLOR{
case(r,{},{r:=0});
case(g,{},{g:=0});
case(b,{},{b:=0});
SNDMSG({erande_f.snd});
footnote({背景色の変更をします});
loop({
select({背景色の変更をします}|
{ 現在は r=}|r|{ g=}|g|{ b=}|b|{ です},
99999,{im({No})},
{赤↑},{case(r<251,{Yes},{r:=r+5;backclr(r,g,b)});im({Yes})},
{赤↓},{case(r> 4,{Yes},{r:=r-5;backclr(r,g,b)});im({Yes})},
{緑↑},{case(g<251,{Yes},{g:=g+5;backclr(r,g,b)});im({Yes})},
{緑↓},{case(g> 4,{Yes},{g:=g-5;backclr(r,g,b)});im({Yes})},
{青↑},{case(b<251,{Yes},{b:=b+5;backclr(r,g,b)});im({Yes})},
{青↓},{case(b> 4,{Yes},{b:=b-5;backclr(r,g,b)});im({Yes})},
{終了},{im({No})});
});
};
/* モデムの設定 */
%setAT{
SNDMSG({erande_f.snd});
footnote({どういうタイプのモデムですか?});
var TYPE[10];
TYPE:=@select({どういうタイプのモデムですか?},
99999,{im({1200n})},
{ 1200 MNPなし },{im({1200n})},
{ 2400 MNPなし },{im({2400n})},
{ 2400(端末速度2400) MNPあり },{im({2400m})},
{ 2400(端末速度4800) MNPあり },{im({4800m})},
{ 2400以上(端末速度9600以上) MNPあり },{im({9600m})});
SNDMSG({nyuryo_f.snd});
footnote({ATコマンドを設定して下さい});
%a @input( {ATコマンドを設定して下さい\n}|
{ (例)ATX3\N3\V1\Q3\J0},,
{AT}|@head(modem,{/}));
case (a<>{},
{Yes}, {case (@getchar(a,1,2),
{AT}, {case ( a = @head(a,{\}),
{Yes}, {modem:=@getchar(a,3,999)|{/}|
@getchar(a,3,999)|
{/AT直接指定_}|TYPE;},,
{modem:=@getchar(a,3,999)|{/}|
{/AT直接指定_}|TYPE;});});},
{No},setAT);
};
%FUJITSU{
%Modem {case (modem,
{}, {im({未設定})},,
{head(@tail(modem,{/}),{_})})};
SNDMSG({erande_f.snd});
footnote({モデムの機種を選択して下さい});
select({モデムの機種を選択して下さい 現在は }|@Modem|{ です},
99999,,
{内蔵1200},{modem:={X3//内蔵1200_1200n}},
{内蔵2400},{modem:={X3/\N3\V1\Q3\J0%C0/内蔵2400_9600m}},
{富士通 PM1200F},{modem:={X3//PM1200F_1200n}},
{富士通 PM2400F},{modem:={X3/\N3\V1\Q3\J0%C0/PM2400F_9600m}},
{富士通 PM2400FII},
{modem:={X3/\N7\V1\Q3\J0\V2%C0/PM2400FII_9600m}},
{富士通 OAMD-301},{modem:={X3&D2/\N3\Q3\J0\V2/OAMD-301_9600m}},
{ATコマンド直設定 },setAT,
{変更しない},)
};
%AIWA{
%Modem {case (modem,
{}, {im({未設定})},,
{head(@tail(modem,{/}),{_})})};
SNDMSG({erande_f.snd});
footnote({モデムの機種を選択して下さい});
select({モデムの機種を選択して下さい 現在は }|@Modem|{ です},
99999,,
{AIWA PV-A1200},{modem:={X3//PV-A1200_1200n}},
{AIWA PV-A2400},{modem:={X3//PV-A2400_2400n}},
{AIWA PV-A2400MNP4},{modem:={&D2/&M4\Q1/PV-A2400MNP4_9600m}},
{AIWA PV-A24MNP5},{modem:={X3&D2/\N3\Q3\J0/PV-A24MNP5_9600m}},
{AIWA PV-A24V42},{modem:={X3&D2/\N3\Q3\J0/PV-A24V42_9600m}},
{AIWA PV-M24},{modem:={X3&D2/\N3\Q3\J0\V2/PV-M24_9600m}},
{AIWA PV-M24M5},{modem:={X3&D2/\N3\Q3\J0\V2/PV-M24M5_9600m}},
{AIWA PV-M24B5},{modem:={X3&D2/\N3\Q3\J0\V2%C0/PV-M24B5_9600m}},
{AIWA PV-A96V5},{MODEM:={X3&D2/\N3\Q3\J0\V2%C0/PV-A96V5_9600m}},
{ATコマンド直設定 },setAT,
{変更しない},)
};
%OMRON{
%Modem {case (modem,
{}, {im({未設定})},,
{head(@tail(modem,{/}),{_})})};
SNDMSG({erande_f.snd});
footnote({モデムの機種を選択して下さい});
select({モデムの機種を選択して下さい 現在は }|@Modem|{ です},
99999,,
{OMRON MD1200},{modem:={X3//MD1200_1200n}},
{OMRON MD12FS},{modem:={X3//MD12FS_1200n}},
{OMRON MD2400F},{modem:={X3/\N3\V1\Q2\J0/MD2400F_2400m}},
{OMRON MD24FB5V},{modem:={X3/\N3\Q2\J0\V2%C0/MD24FB5V_9600m}},
{OMRON MD24FP4},{modem:={X3/\N3\Q2\J0/MD24FP4_2400m}},
{OMRON MD24FP4II},{modem:={X3&P2/\N3\Q2\J0/MD24FP4II_9600m}},
{OMRON MD24FP5V},{modem:={X3/\N3\Q2\J0\V2%C0/MD24FP5V_9600m}},
{OMRON MD24FS4},{modem:={X3/\N3\Q2\J0/MD24FS4_2400m}},
{OMRON MD24FS5},{modem:={X3/\N3\Q2\J0/MD24FS5_2400m}},
{OMRON MD24FS7},{modem:={X3/\N3\Q2\J0/MD24FS7_2400m}},
{ATコマンド直設定 },setAT,
{変更しない},)
};
%EPSON{
%Modem {case (modem,
{}, {im({未設定})},,
{head(@tail(modem,{/}),{_})})};
SNDMSG({erande_f.snd});
footnote({モデムの機種を選択して下さい});
select({モデムの機種を選択して下さい 現在は }|@Modem|{ です},
99999,,
{EPSON SR-120S},{modem:={X3//SR-120S_1200n}},
{EPSON SR-240AT},{modem:={X3//SR-240AT_2400n}},
{EPSON SR-240V},{modem:={X3\V2/N1&K1%C0/SR-240V_9600m}},
{ATコマンド直設定 },setAT,
{変更しない},)
};
%NEC{
%Modem {case (modem,
{}, {im({未設定})},,
{head(@tail(modem,{/}),{_})})};
SNDMSG({erande_f.snd});
footnote({モデムの機種を選択して下さい});
select({モデムの機種を選択して下さい 現在は }|@Modem|{ です},
99999,,
{NEC COMSTAR 2424},{modem:={X3/\N3\Q2/COMSTAR 2424_2400m}},
{ATコマンド直設定 },setAT,
{変更しない},)
};
%SONY{
%Modem {case (modem,
{}, {im({未設定})},,
{head(@tail(modem,{/}),{_})})};
SNDMSG({erande_f.snd});
footnote({モデムの機種を選択して下さい});
select({モデムの機種を選択して下さい 現在は }|@Modem|{ です},
99999,,
{SONY IT-V1200},{modem:={X3//IT-V1200_1200n}},
{ATコマンド直設定 },setAT,
{変更しない},)
};
%MICROCORE{
%Modem {case (modem,
{}, {im({未設定})},,
{head(@tail(modem,{/}),{_})})};
SNDMSG({erande_f.snd});
footnote({モデムの機種を選択して下さい});
select({モデムの機種を選択して下さい 現在は }|@Modem|{ です},
99999,,
{MICROCORE MS24PA5},{modem:={X3/\N3\Q2\J0\X1%C0/MC24PA5_9600m}},
{ATコマンド直設定 },setAT,
{変更しない},);
};
%SETMODEM{
%Modem {case (modem,
{}, {im({未設定})},,
{head(@tail(modem,{/}),{_})})};
SNDMSG({erande_f.snd});
footnote({モデムのメーカーを選択して下さい});
select({モデムのメーカーを選択して下さい},
99999,,
{ FUJITSU },FUJITSU,
{ AIWA },AIWA,
{ OMRON },OMRON,
{ EPSON },EPSON,
{ NEC },NEC,
{ SONY },SONY,
{ マイクロコア },MICROCORE,
{ ATコマンド直設定 },setAT);
};
/* 設定情報をファイルに保存する */
%writeSET{
setcdir(DIR1);
dispoff({Yes});
command({copy }|SETFILE|{ PVAPSET.BAK});
delfile(SETFILE);
dispoff({No});
write (SETFILE,
{ID :=}|@xc({7b})|ID |@xc({7d})|{;\n}|
{PASS :=}|@xc({7b})|PASS |@xc({7d})|{;\n}|
{AP :=}|@xc({7b})|AP |@xc({7d})|{;\n}|
{AP2 :=}|@xc({7b})|AP2 |@xc({7d})|{;\n}|
{AP3 :=}|@xc({7b})|AP3 |@xc({7d})|{;\n}|
{TEL :=}|@xc({7b})|TEL |@xc({7d})|{;\n}|
{MODEM :=}|@xc({7b})|MODEM |@xc({7d})|{;\n}|
{SAVE :=}|@xc({7b})|SAVE |@xc({7d})|{;\n}|
{SAVE2 :=}|@xc({7b})|SAVE2 |@xc({7d})|{;\n}|
{LIST :=}|@xc({7b})|LIST |@xc({7d})|{;\n}|
{UPDOWN :=}|@xc({7b})|UPDOWN |@xc({7d})|{;\n});
write (SETFILE,
{BILLCHK :=}|@xc({7b})|BILLCHK |@xc({7d})|{;\n}|
{PRESER :=}|@xc({7b})|PRESER |@xc({7d})|{;\n}|
{ACCEAP :=}|@xc({7b})|ACCEAP |@xc({7d})|{;\n}|
{REDIAL :=}|@xc({7b})|REDIAL |@xc({7d})|{;\n}|
{CALAMI :=}|@xc({7b})|CALAMI |@xc({7d})|{;\n}|
{LOGPATH :=}|@xc({7b})|LOGPATH |@xc({7d})|{;\n}|
{TEMPPATH :=}|@xc({7b})|TEMPPATH|@xc({7d})|{;\n}|
{DIR2 :=}|@xc({7b})|DIR2 |@xc({7d})|{;\n}|
{TITLEPATH:=}|@xc({7b})|TITLEPATH|@xc({7d})|{;\n}|
{SOUND :=}|@xc({7b})|SOUND |@xc({7d})|{;\n}|
{VBELL :=}|@xc({7b})|VBELL |@xc({7d})|{;\n}|
{BELFIL :=}|@xc({7b})|BELFIL |@xc({7d})|{;\n});
write (SETFILE,
{FMGR :=}|@xc({7b})|FMGR |@xc({7d})|{;\n}|
{r :=}|@xc({7b})|r |@xc({7d})|{;\n}|
{g :=}|@xc({7b})|g |@xc({7d})|{;\n}|
{b :=}|@xc({7b})|b |@xc({7d})|{;\n});
SETFILE1:={標準設定};
};
/* 設定情報を元に戻す */
%CANCEL{
SNDMSG({kaknin_f.snd});
footnote({本当に元に戻してもいいですか?});
select({本当に元に戻してもいいですか?},
99999,,
{ O K },{case (@filechk(SETFILE),
{Yes}, {setcdir(DIR1);
#PVAPSET.SET;
init;
SETFILE1:={標準設定};})},
{ N G },);
};
/* 設定情報をファイルに保存する */
%FSAVE{
var newfile[64];
SNDMSG({nyuryo_f.snd});
footnote({設定情報を保存するファイルを指定して下さい});
newfile:=@filesel({USR});
case (newfile<>{},
{Yes}, {%newdir @getcdir;
case (@nochar(newdir)==3,
{Yes}, {newfile:=newdir|newfile},
{No}, {newfile:=newdir|{\}|newfile});
delfile(newfile);
write(newfile,
{ID :=}|@xc({7b})|ID |@xc({7d})|{;\n}|
{PASS :=}|@xc({7b})|PASS |@xc({7d})|{;\n}|
{AP :=}|@xc({7b})|AP |@xc({7d})|{;\n}|
{AP2 :=}|@xc({7b})|AP2 |@xc({7d})|{;\n}|
{AP3 :=}|@xc({7b})|AP3 |@xc({7d})|{;\n}|
{TEL :=}|@xc({7b})|TEL |@xc({7d})|{;\n}|
{MODEM :=}|@xc({7b})|MODEM |@xc({7d})|{;\n}|
{SAVE :=}|@xc({7b})|SAVE |@xc({7d})|{;\n}|
{SAVE2 :=}|@xc({7b})|SAVE2 |@xc({7d})|{;\n}|
{LIST :=}|@xc({7b})|LIST |@xc({7d})|{;\n}|
{UPDOWN :=}|@xc({7b})|UPDOWN |@xc({7d})|{;\n});
write(newfile,
{BILLCHK :=}|@xc({7b})|BILLCHK |@xc({7d})|{;\n}|
{PRESER :=}|@xc({7b})|PRESER |@xc({7d})|{;\n}|
{ACCEAP :=}|@xc({7b})|ACCEAP |@xc({7d})|{;\n}|
{REDIAL :=}|@xc({7b})|REDIAL |@xc({7d})|{;\n}|
{CALAMI :=}|@xc({7b})|CALAMI |@xc({7d})|{;\n}|
{LOGPATH :=}|@xc({7b})|LOGPATH |@xc({7d})|{;\n}|
{TEMPPATH :=}|@xc({7b})|TEMPPATH|@xc({7d})|{;\n}|
{DIR2 :=}|@xc({7b})|DIR2 |@xc({7d})|{;\n}|
{TITLEPATH:=}|@xc({7b})|TITLEPATH|@xc({7d})|{;\n}|
{SOUND :=}|@xc({7b})|SOUND |@xc({7d})|{;\n}|
{VBELL :=}|@xc({7b})|VBELL |@xc({7d})|{;\n}|
{BELFIL :=}|@xc({7b})|BELFIL |@xc({7d})|{;\n});
write(newfile,
{FMGR :=}|@xc({7b})|FMGR |@xc({7d})|{;\n}|
{r :=}|@xc({7b})|r |@xc({7d})|{;\n}|
{g :=}|@xc({7b})|g |@xc({7d})|{;\n}|
{b :=}|@xc({7b})|b |@xc({7d})|{;\n});
});
setcdir(DIR1);
};
/* ファイルから設定情報を読み込む */
%FLOAD{
var newfile[64];
SNDMSG({nyuryo_f.snd});
footnote({設定情報を読み込むファイルを指定して下さい});
newfile:=@filesel({USR});
case (newfile<>{},
{Yes}, {%newdir @getcdir;
case (@nochar(newdir)==3,
{Yes}, {newfile:=newdir|newfile},
{No}, {newfile:=newdir|{\}|newfile});
case (@filechk(newfile),
{Yes}, {%ExcPilot {#}|newfile;
ExcPilot;
init;
SETFILE1:=@tail(newfile,{\});});});
setcdir(DIR1);
};
/* 実行 */
USERSET;